DragHandler QML Type

Handler for dragging More...

Import Statement: import Qt.labs.handlers 1.0
Inherits:

SinglePointHandler

Properties

Signals

Detailed Description

DragHandler is a handler that is used to interactively move an Item. Like other Pointer Handlers, by default it is fully functional, and manipulates its target.

import QtQuick 2.10
import Qt.labs.handlers 1.0

Rectangle {
    width: 100
    height: 100
    color: "lightsteelblue"
    DragHandler { }
}

It has properties to restrict the range of dragging.

If it is declared within one Item but is assigned a different target, then it handles events within the bounds of the parent Item but manipulates the target Item instead:

import QtQuick 2.10
import Qt.labs.handlers 1.0

Item {
    width: 640
    height: 480

    Rectangle {
        id: feedback
        border.color: "red"
        width: Math.max(10, handler.point.ellipseDiameters.width)
        height: Math.max(10, handler.point.ellipseDiameters.height)
        radius: Math.max(width, height) / 2
        visible: handler.active
    }

    DragHandler {
        id: handler
        target: feedback
    }
}

A third way to use it is to set target to null and react to property changes in some other way:

import QtQuick 2.10
import Qt.labs.handlers 1.0

Item {
    width: 640
    height: 480

    DragHandler {
        id: handler
        target: null
    }

    Text {
        color: handler.active ? "darkgreen" : "black"
        text: handler.point.position.x.toFixed(1) + "," + handler.point.position.y.toFixed(1)
        x: handler.point.position.x - width / 2
        y: handler.point.position.y - height
    }
}

At this time, drag-and-drop is not yet supported.

See also Drag and MouseArea.

Property Documentation

acceptedButtons : int

The mouse buttons which can activate this Pointer Handler.

By default, this property is set to Qt.LeftButton. It can be set to an OR combination of mouse buttons, and will ignore events from other buttons.

For example, a control could be made to respond to left and right clicks in different ways, with two handlers:

Item {
    TapHandler {
        onTapped: console.log("left clicked")
    }
    TapHandler {
        acceptedButtons: Qt.RightButton
        onTapped: console.log("right clicked")
    }
}

Note: Tapping on a touchscreen or tapping the stylus on a graphics tablet emulates clicking the left mouse button. This behavior can be altered via acceptedDevices or acceptedPointerTypes.


acceptedDevices : int

The types of pointing devices that can activate this Pointer Handler.

By default, this property is set to PointerDevice.AllDevices. If you set it to an OR combination of device types, it will ignore events from non-matching devices.

For example, a control could be made to respond to mouse and stylus clicks in one way, and touchscreen taps in another way, with two handlers:

Item {
   TapHandler {
       acceptedDevices: PointerDevice.Mouse | PointerDevice.Stylus
       onTapped: console.log("clicked")
   }
   TapHandler {
       acceptedDevices: PointerDevice.TouchScreen
       onTapped: console.log("tapped")
   }
}

acceptedModifiers : int

If this property is set, it will require the given keyboard modifiers to be pressed in order to react to pointer events, and otherwise ignore them.

If this property is set to Qt.KeyboardModifierMask (the default value), then the PointerHandler ignores the modifier keys.

For example, an Item could have two handlers of the same type, one of which is enabled only if the required keyboard modifiers are pressed:

Item {
   TapHandler {
       acceptedModifiers: Qt.ControlModifier
       onTapped: console.log("control-tapped")
   }
   TapHandler {
       acceptedModifiers: Qt.NoModifier
       onTapped: console.log("tapped")
   }
}

acceptedPointerTypes : int

The types of pointing instruments (finger, stylus, eraser, etc.) that can activate this Pointer Handler.

By default, this property is set to PointerDevice.AllPointerTypes. If you set it to an OR combination of device types, it will ignore events from non-matching events.

For example, a control could be made to respond to mouse, touch, and stylus clicks in some way, but delete itself if tapped with an eraser tool on a graphics tablet, with two handlers:

Rectangle {
   id: rect
   TapHandler {
       acceptedPointerTypes: PointerDevice.GenericPointer | PointerDevice.Finger | PointerDevice.Pen
       onTapped: console.log("clicked")
   }
   TapHandler {
       acceptedPointerTypes: PointerDevice.Eraser
       onTapped: rect.destroy()
   }
}

[read-only] active : bool

This holds true whenever this PointerHandler has taken sole responsibility for handing one or more EventPoints, by successfully taking an exclusive grab of those points. This means that it is keeping its properties up-to-date according to the movements of those Event Points and actively manipulating its target (if any).


enabled : bool

If a PointerHandler is disabled, it will reject all events and no signals will be emitted.


grabPermission : bool

This property specifies the permissions when this handler's logic decides to take over the exclusive grab, or when it is asked to approve grab takeover or cancellation by another handler.

The default is CanTakeOverFromItems | CanTakeOverFromHandlersOfDifferentType | ApprovesTakeOverByAnything which allows most takeover scenarios but avoids e.g. two PinchHandlers fighting over the same touchpoints.


[read-only] parent : Item

The Item which is the scope of the handler; the Item in which it was declared. The handler will handle events on behalf of this Item, which means a pointer event is relevant if at least one of its event points occurs within the Item's interior. Initially target() is the same, but target() can be reassigned.

See also QQuick::PointerHandler::target() and QObject::parent().


[read-only] point : HandlerPoint

The event point currently being handled. When no point is currently being handled, this object is reset to default values (all coordinates are 0).


target : Item

The Item which this handler will manipulate.

By default, it is the same as the parent: the Item within which the handler is declared. However, it can sometimes be useful to set the target to a different Item, in order to handle events within one item but manipulate another; or to null, to disable the default behavior and do something else instead.


[read-only] translation : QVector2D

The translation since the gesture began.


xAxis group

xAxis and yAxis control the constraints for horizontal and vertical dragging, respectively.

ConstantDescription
minimumThe minimum acceptable value of x or y to be applied to the target
maximumThe maximum acceptable value of x or y to be applied to the target
enabledWhether dragging in this direction is allowed at all

Signal Documentation

canceled(EventPoint point)

If this handler has already grabbed the given point, this signal is emitted when the grab is stolen by a different Pointer Handler or Item.


grabChanged(EventPoint point)

This signal is emitted when this handler has acquired or relinquished a passive or exclusive grab of the given point.


© 2017 The Qt Company Ltd. Documentation contributions included herein are the copyrights of their respective owners. The documentation provided herein is licensed under the terms of the GNU Free Documentation License version 1.3 as published by the Free Software Foundation. Qt and respective logos are trademarks of The Qt Company Ltd. in Finland and/or other countries worldwide. All other trademarks are property of their respective owners.