QT = qtsaferenderer qsrplatformadaptation
CONFIG += c++11

SOURCES += main.cpp

RESOURCES += qml.qrc \
    images.qrc

# Additional import path used to resolve QML modules in Qt Creator's code model
QML_IMPORT_PATH =

# Default rules for deployment.
qnx: target.path = /tmp/saferenderer/$${TARGET}
else: target.path = $$[QT_INSTALL_EXAMPLES]/saferenderer/$${TARGET}
INSTALLS += target

CONFIG += qtsaferenderer exceptions
SAFE_QML = $$PWD/SafeUI.qml
SAFE_LAYOUT_PATH = $$PWD/layoutData
SAFE_LAYOUT_FONTS = $$PWD/fonts
SAFE_RESOURCES += safeasset.qrc
SAFE_LANGUAGES = en fi de uk el ar da et no sv

#Localization
SAFE_TRANSLATION = $$PWD/translationFiles/safeui
TRANSLATIONS += translationFiles/safeui_en.ts translationFiles/safeui_fi.ts translationFiles/safeui_de.ts translationFiles/safeui_uk.ts translationFiles/safeui_el.ts translationFiles/safeui_ar.ts translationFiles/safeui_da.ts translationFiles/safeui_et.ts translationFiles/safeui_no.ts translationFiles/safeui_sv.ts
lupdate_only {
    SOURCES+=SafeUI.qml
}

#Run the lrelease tool to generate the qm files
qtPrepareTool(QMAKE_LRELEASE, lrelease)
command = $$QMAKE_LRELEASE_EXE $$TRANSLATIONS
system($$command)|error("Failed to run: $$command")

!cross_compile: DEFINES += HOST_BUILD

OTHER_FILES += \
    SafeUI.qml