/******************************************************************************
**
** Copyright (C) 2020 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Qt Quick Ultralite module.
**
** $QT_BEGIN_LICENSE:COMM$
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** $QT_END_LICENSE$
**
******************************************************************************/

import Automotive
import QtQuick 2.15
import QtQuickUltralite.Extras 2.0

Row {
    id: root
    visible: QulPerf.enabled

    property real currentFps: QulPerf.fps
    property real averageFps: 0

    property real fpsSampleSum: 0
    property int fpsSampleCount: 0

    property bool isSportMode: MainModel.clusterMode == MainModel.ModeSport

    onIsSportModeChanged: {
        if (!isSportMode && fpsSampleCount > 0) {
            updateAverageFpsTimer.start()
        }
    }

    Timer {
        id: updateAverageFpsTimer
        interval: 2000
        onTriggered: {
            averageFps = fpsSampleSum / fpsSampleCount
        }
    }

    Timer {
        id: fpsSampleTimer
        interval: 1000
        running: true
        repeat: true
        onTriggered: {
            if (currentFps > 0) {
                fpsSampleSum += currentFps
                fpsSampleCount++
            }
        }
    }

    PerformanceMetricItem {
        label: "FPS:"
        value: QulPerf.fps.toFixed(1)
    }

    PerformanceMetricItem {
        label: "FPS (avg):"
        value: averageFps.toFixed(1)
    }

    PerformanceMetricItem {
        label: "Text layout:"
        value: (QulPerf.textLayout * 10).toFixed(1)
        unit: "‰"
    }

    PerformanceMetricItem {
        label: "Text blend:"
        value: (QulPerf.textBlend * 10).toFixed(1)
        unit: "‰"
    }

    PerformanceMetricItem {
        label: "Rect fill/blend:"
        value: ((QulPerf.rectFill + QulPerf.rectBlend) * 10).toFixed(1)
        unit: "‰"
    }

    PerformanceMetricItem {
        label: "Image blend:"
        value: (QulPerf.imageBlend * 10).toFixed(1)
        unit: "‰"
    }

    PerformanceMetricItem {
        label: "Image transform:"
        value: (QulPerf.imageTransform * 10).toFixed(1)
        unit: "‰"
    }
}