// Copyright (C) 2024 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial
import QtQuick 2.15
import Thermo 1.0

Rectangle {
    id: root

    property int selected

    signal viewSwitched(int index)

    color: "white"

    Row {
        id: row
        anchors.fill: parent

        Repeater {
            delegate: Item {
                required property int index
                required property string title

                height: root.height
                width: root.width / 3

                MouseArea {
                    anchors.fill: parent
                    // improve clickability
                    anchors.topMargin: -15

                    onClicked: root.viewSwitched(parent.index)
                }
                Text {
                    anchors.centerIn: parent
                    color: root.selected === parent.index ? ColorStyle.blue : ColorStyle.greyDark4
                    font.pixelSize: Theme.bottomBarFontSize
                    text: parent.title
                }
                Image {
                    anchors.bottom: parent.bottom
                    anchors.horizontalCenter: parent.horizontalCenter
                    source: "selected.png"
                    visible: root.selected === parent.index
                }
            }
            model: ListModel {
                ListElement {
                    //% "Places"
                    title: qsTrId("id-places")
                }
                ListElement {
                    //% "Schedule"
                    title: qsTrId("id-schedule")
                }
                ListElement {
                    //% "Stats"
                    title: qsTrId("id-stats")
                }
            }
        }
    }
}